add spell school to available spells?

[Xykal]

Originally Posted by ShadowChemosh

Well yea that would make a difference.

@Xykal change the timing to what Mathias mentions and see if that gets you going.

Spell level are also tags. So level one is "sLevel.1" level 2 would be "sLevel.2". So you can add that logic to the school to limit the use to specific spells levels...

I'm confused as to what I should change the timing to. Final / 10,000 won't work?

[Xykal]

Unfortunately I can't seem to get this to work. This is how the eval script reads right now:

~ Add transmutation school to spell list
hero.childfound[cHelpWit].field[cSpellExpr].text &= "|sSchool.Transmutat"

The phase is "Final Phase" and the Priority is 7000 (although I've tried a number of priorities from 100 to 11000.

[Mathias]

I think the correct timing is more like Final/999999999

[Xykal]

Originally Posted by Mathias

I think the correct timing is more like Final/999999999

Hrrmm... still not working. Is there something else I could be missing?

[AndrewD2]

well the Red Mantis Assassin uses this at Post-Levels 10,500

      ~ in addition to class-specific spells, we're also allowed Sor/Wiz spells from the Illusion and Transmutation schools
      field[cSpellExpr].text = "(" & field[cSpellExpr].text & ") | ((sClass.cHelpSor | sClass.cHelpWiz) & (sSchool.Illusion | sSchool.Transmutat))"

So I would try the Post-Level timing

[ShadowChemosh]

Blah what we all forgot is that a Witch has a "Spellbook"! So we have to modify the spellbook expression and the normal spell expression. It causes some issues because of this spellbook as we only want to be able to prepare the spells chosen on the spellbook. Sigh so what I did was use the portal.ClsBook tag to allow anything chosen on the spellbook to let those be prepared also.

The issue with using portal.ClsBook means if you have a "witch/wizard" it will let you select spells from the wizards spellbook. Sigh... But I am going to just hope you don't need to support a witch/wizard!!!!!

Here is the working script:
Post-Levels/10500

~ If we're disabled, do nothing
doneif (tagis[Helper.FtDisable] <> 0)
~ If no witch class get out now!
doneif (hero.childlives[cHelpWit] <> 1)

~ Add transmutation school and spells picked from spell book
hero.childfound[cHelpWit].field[cSpellExpr].text &= " | (sSchool.Transmutat & portal.ClsBook)"

~ Add transmutation school  to spell book and specific spell levels here
hero.childfound[cHelpWit].field[cSplBkExpr].text &= " | ((!Hide.Spell & !Helper.Obsolete & !Helper.Helper) & (sSchool.Transmutat & (" & tagids[sLevel.?,"|"] & ")))"

The important thing is that the "spell levels" are getting grabbed from the "sLevel.?" tag you assign to the feat itself. So the first feat needs to have sLevel.0,sLevel.1,sLevel.2, and sLevel.3 added to the feat. The "tagids[]" is going to create a list of spell levels based on the sLevel.? tags on the feat when it runs. Making the levels soft-coded.

You do this by pressing the blue "Tags" button on the right:
Noname.jpg

Then your 2nd feat script can then assign the additional level tags to the feat at Post-Levels/10000 which is BEFORE the script on the first feat runs.

Post-Levels/10000:

~ If we're disabled, do nothing
doneif (tagis[Helper.FtDisable] <> 0)
~ If no feat get out now!
doneif (hero.childlives[fWitchXXXX] <> 1)

~ Give access to level 4 to 6
perform hero.child[fWitchXXXX].assign[sLevel.4]
perform hero.child[fWitchXXXX].assign[sLevel.5]
perform hero.child[fWitchXXXX].assign[sLevel.6]

The red feat ID will need to be changed to match your unique ID. Then you just need a third feat to assign levels 7,8,9.

[Xykal]

Wow... thanks so much. That works like a charm! =)

[Xykal]

So that added the spells to my spell list, but they don't seem to be showing up on the list of available options for mythic spellcasting.

Any thoughts?

[ShadowChemosh]

Originally Posted by Xykal

So that added the spells to my spell list, but they don't seem to be showing up on the list of available options for mythic spellcasting.

Any thoughts?

Yep you have to modify the Mythic Helper spell expression also then. Again I say the below does not work with multiple classes. If you want that you would have to make the script be smarter by figuring out the spellcasting classes and adding in the sClass.? tags. So this is hard coded currently only to work with a witch class.

Final-Phase/99999999999999

~ If we're disabled, do nothing
doneif (tagis[Helper.FtDisable] <> 0)
~ If no mythic helper get out now!
doneif (hero.childlives[MythHelper] <> 1)

hero.child[MythHelper].field[mhSplExpr].text ="component.BaseSpell & !fieldisempty:sMythic & (sClass.cHelpWit|sSchool.Transmutat) & !Helper.Helper & !Helper.Obsolete"

[Xykal]

That works perfectly. Thank you again for all your help!! =)