[ShadowChemosh]

Originally Posted by Born8342

Hi Shadow Chemosh. That cleared the problem with the error showing, now for the next question, how do I get it calculate my dex indstead og my str to dmg? I have the other prereg. (My dm have ruled that when I have Bladed Brush I can use Slashing Grace).

Thanks for all the assistance

This feat has had some major changes done to it sense Mathias originally posted. To get this to full work requires the 2nd script to also be changed now.

Totally replace the second script with this version:

      ~ If we're disabled, do nothing
      doneif (tagis[Helper.FtDisable] <> 0)

      ~ Equipping a shield or another weapon in our off hand negates our bonuses
      ~ Unless that off hand shield is a buckler (This is a FAQ from July 2015)
      if (hero.tagis[Hero.GraceTWF] = 0) then
        doneif (hero.tagexpr[Hero.EquipOff | (Hero.EquipShld & !Hero.ShldOffOK)] <> 0)
        endif

      ~ If we're not chosen, get out now
      doneif (field[usrChosen1].ischosen + tagis[Target.?] = 0)

      ~ The construction of this search expression is complicated because we
      ~ need to allow Martial Versatility to expand the affected weapons, but
      ~ only to those weapons this feat could normally select. Thus we create
      ~ the base expression, and append some expansions if the appropriate feats
      ~ are present.
      var searchexpr as string
      searchexpr = " & !(fieldval:gIsEquip <> 0 & fieldval:wIs2nd <> 0) & (wClass.Light | wClass.OneHanded) & wType.S"

      if (tagcount[Hero.MartVersa] + hero.tagcount[Hero.MartMaster] + tagcount[Hero.MyMartVers] + hero.tagcount[Hero.MyMartMast] <> 0) then
        searchexpr = tagids[wFtrGroup.?, " | "] & searchexpr
      else
        if (tagis[Target.?] <> 0) then
          searchexpr = tagids[Target.?, " | "] & searchexpr
        else
          searchexpr = field[usrChosen1].chosen.tagids[IsWeapon.?, " | "] & searchexpr & " | " & field[usrChosen1].chosen.tagids[IsWeapon.?, " | "]
          endif
        endif

      foreach pick in hero from BaseWep where searchexpr
        perform eachpick.assign[DamageOpt.aDEX]
        nexteach

That will cause the Glaive in this case to use Dex to damage.