Racial Ability 2

[Manalishi66]

Tying to code the following....but I'm getting no where.....what the right track?

You gain a +2 natural armor bonus to Armor Class when wearing leather or hide armor. You do not gain this bonus if you are wearing, wielding, or holding anything made out of metal.

Code (pre Att, 10000)

~ Loop through all armor and weapons of metal material
foreach pick in container where "EquipType.Metal"

~ Add a -2 to our armor class
if (each.tagis[EquipType.Metal] <> 1) then
hero.child[ArmorClass].field[Bonus].value -= 2
endif
nexteach

Am I even close? Help!

P.S., I compiles without errors...but it does nothing?

 

[ShadowChemosh]

Yea I would say close. The general idea is right but you need to set a variable instead of the AC directly. This is because you want to loop through all items first.

My question is based on the rules wording its ok to carry such an item but only when equipped does it negate the +2 bonus right? That makes it a little more complex then.

Lets fix the idea you have working and I would move the timing up in this case to
Post-Levels/10000:

var nValid as number

[B][COLOR="Green"]~ Set our armor bonus value here so that outside
~ scripts can adjust us if needed.[/COLOR][/B]
field[abValue].value += 2

[B][COLOR="Green"]~ Set to one as we assume we are valid unless
~ we specifically find metal equipment.[/COLOR][/B]
nValid = 1
[B][COLOR="Green"]
~ Loop through all picks on the hero that have the
~ Metal tag.[/COLOR][/B]
foreach pick in hero where "EquipType.Metal"
  [B][COLOR="Green"]~ We found a metal item so we are no longer valid[/COLOR][/B]
  nValid = 0
nexteach

[B][COLOR="Green"]~ if we are not valid get out now![/COLOR][/B]
doneif (nValid <> 1) 
[B][COLOR="Green"]
~ Give a bonus to AC[/COLOR][/B]
hero.child[ArmorClass].field[tACNatural].value += field[abValue].value

Here is a more complex script that actually makes sure a character is wearing or wielding the said weapon/armor:
Post-levels/10000

var nValid  as number

[B][COLOR="Green"]~ Set our armor bonus value here so that outside
~ scripts can adjust us if needed.[/COLOR][/B]
field[abValue].value += 2
[B][COLOR="Green"]
~ Set to one as we assume we are valid unless
~ we specifically find metal equipment.[/COLOR][/B]
nValid  = 1

[B][COLOR="Green"]~ Loop through all picks on the hero that have the
~ Metal tag.[/COLOR][/B]
foreach pick in hero where "EquipType.Metal"

  [B][COLOR="Green"]~ if we are weapon then check here[/COLOR][/B]
  if (each.tagis[component.BaseWep] <> 0) then

    [B][COLOR="Green"]~ lets see if we are equipped in either hand?[/COLOR][/B]
    if (each.field[wIs2nd].value + each.field[gIsEquip].value <> 0) then

      [COLOR="Green"][B]~ we are a metal weapon that is equipped so we are not valid[/B][/COLOR]
      nValid  = 0

    endif

  [B][COLOR="Green"]~..if we are armor then check here[/COLOR][/B]
  elseif (each.tagis[component.BaseArmor] <> 0) then

    [B][COLOR="Green"]~ lets see if we are equipped?[/COLOR][/B]
    if (each.field[gIsEquip].value <> 0) then

      [B][COLOR="Green"]~ we are a metal armor that is equipped we are not valid[/COLOR][/B]
      nValid  = 0

    endif
  endif  

nexteach

[B][COLOR="Green"]~ if we are not valid get out now![/COLOR][/B]
doneif (nValid  <> 1) 

[B][COLOR="Green"]~ Give a bonus to AC[/COLOR][/B]
hero.child[ArmorClass].field[tACNatural].value += field[abValue].value

 

[AndrewD2]

Only thing I'd note is it's a Natural armor so you need to add to field tACNatural not Bonus

 

[ShadowChemosh]

Only thing I'd note is it's a Natural armor so you need to add to field tACNatural not Bonus

Picky picky... I updated the scripts...

 

[Manalishi66]

Sorry for the late response. Worked Great! That was a tough one for me. Again... Thanks to everyone!

Don