Adjusting Power Attack Fear

[Krothos]

Adjusting Power Attack Feat

In my campaign, we play with a modified Power Attack feat. The feat does not increase damage by *1.5. So a 1st level fighter with a greatsword would only get +2 damage when using Power Attack.

I have looked at the Tools, and pulled up a copy of the Power Attack data file. I can see the evaluation scripts, min requirements, but cannot locate the actual fields that would allow me to make the change necessary to match my campaign's house rule.

I successfully created a new Power Attack user file, with a unique identifier, name, and updated text. This test successfully in the software, and I was able to selected in HL. But it still +3 damage when I enable the feat with a greatsword.

Please help. Still trying to muck my way through the scripting of this great program. Thanks!

 

[Aaron]

Adjusting Power Attack is actually one of the examples used in the "Hero Lab Intro to Adding Content" seminar I ran last year. You might want to check it out here:

https://www.youtube.com/watch?v=fOHWRXtxlhk

 

[Krothos]

Oh, thank you. This video was extremely helpful.

I do have one question though, my house rule modified Power Attack eliminates the x1.5 bonus for wielding weapons with 2 hands, but leaves the x.5 bonus for off-hand weapons. So with Power Attack enabled, you get either -1/+2 or -1/+1. How would I go about changing this so that the new feat would affect 2-haneded attacks in that manner? It appears that this "bonus" determination is based upon the weapon/attack itself and not Power Attack.

Thanks!

 

[Krothos]

Update... I was able to create a couple of new traits and a feat that we use in our group. So thank you again for the assistance. The Power Attack change is still puzzling me though.

 

[Aaron]

Well, looking into it further, the multiplier used is internal and not able to be manipulated from outside, so I'd recommend applying a damage penalty to two handed weapons to counteract the extra x.5 they get from power attack. There is a field specifically for damage bonuses for 2 handed weapons, but it doesn't apply to 1 handed weapons wielded with 2 hands, so I think you'll have to foreach through all weapons on the hero to apply this. Here is how I would modify the existing scripts.

First (at post level 5000) becomes:

      field[abValue].value += round(#BAB[]/4,0,-1) + 1
      field[abValue2].value += field[abValue].value * 2

      ~ Store half our damage bonus in the third value field, so we can apply
      ~ it as a penalty to offset the extra x.5 added to 2-handed weapons.
      field[abValue3].value -= round(field[abValue2].value/2,0,1)

Second one (at post attr 14000) becomes

      ~ If we're disabled, do nothing
      doneif (tagis[Helper.FtDisable] <> 0)

      doneif (field[abilActive].value = 0)

      hero.child[Attack].field[atmPenalty].value -= field[abValue].value
      hero.child[Damage].field[tDamPower].value += field[abValue2].value
      
      ~ Counteract the extra bonus 2 handed weapons get when power attacking
      var powattmult as number

      foreach pick in hero from BaseWep
        ~First handle manufactured weapons
        if (eachpick.tagis[component.BaseNatWep] = 0) then
          ~Two-Handed weapons have a multiplier of 1.5
          if (eachpick.tagexpr[component.BaseWep & (wClass.TwoHanded | (wClass.OneHanded & fieldval:gSizeDiff = 1) | (wClass.Light & fieldval:gSizeDiff = 2))] <> 0) then
            powattmult = 1.5

            ~ Unless they are double weapons, being wielded doubly.
            if (eachpick.tagis[wCategory.Double] <> 0) then
              if (eachpick.field[wIsDouble].value <> 0) then
                powattmult = 1
                endif
              endif

          ~Any other weapons give a multiplier of 1.5 if equipped in 2 hands. We
          ~don't need to distinguish between one/light because light weapons
          ~equipped with 2 hands already throw an error.
          elseif (eachpick.tagexpr[component.BaseWep & Hero.MainHand & (Hero.OffHand | Helper.PowTwoHand)] <> 0) then
            powattmult = 1.5

          ~weapons equipped in the off hand but not the main hand are halved.
          elseif (eachpick.tagexpr[component.BaseWep & !Hero.MainHand & Hero.OffHand] <> 0) then
            powattmult = .5

          ~and finally everyone else gets just 1 (because we assume they will wield
          ~it in the main hand only unless equipped otherwise).
          else
            powattmult = 1
            endif

        ~Now to handle the natural weapons
        elseif (eachpick.tagis[component.BaseNatWep] <> 0) then
          ~Natural weapons treated as 2 handed use a higher mult, regardless of
          ~their Primary/Secondary attack status.
          if (eachpick.tagis[Helper.NatTwoHand] <> 0) then
            powattmult = 1.5

          ~We could be secondary because we lack NatPrimary, or because we have
          ~it but it has been overridden
          elseif (eachpick.tagexpr[!Helper.NatPrimary | (Helper.NatPrimary & Helper.NatOverSec)] <> 0) then
            powattmult = .5

          ~Any other natural attack is assumed to be primary.
          else
            powattmult = 1
            endif
          endif

        ~ If our multiplier is x1.5, then apply the penalty
        if (powattmult = 1.5) then
          eachpick.field[dmmPenalty].value += field[abValue3].value
          endif
        nexteach

Hope that helps!

 

[Krothos]

Holy... Wow! I didn't realize how involved this project was going to be, as evidence by that script! I'm sure this will help create my feat. Thank you! You, Sir, are awesome!

As a side note, I updated my Gnoll Killer trait and was able to add the trait bonuses to attacks and damage with a In-Play checkbox. All from watching your video.