Psionic Power Points...?

[DannyBoy2k]

That would be LOVELY.

[Aaron]

Alright, I found the issue on our end. It looks like in the calculation script we used a variable "bonus" which had already been used earlier and we forgot to remove the value from it's previous use. This it was always adding the value of the cPsiLevMax field if there were no bonus power points from your attribute.

Here's the offending bit of code, along with the debug statements I used to track the issue down:

      field[cPsiLevMax].value = bonus

      ~ If we have a link to an attribute for bonus power points, get the
      ~ attribute bonus now so we can calculate how many bonus PP we get.
      var bonus as number
      var attrbonus as number
      if (tagis[PsiAttr.?] <> 0) then
debug "We have the tag"
        var searchexpr as string
        searchexpr = tagids[PsiAttr.?,"|"]
        attrbonus = hero.findchild[BaseAttr,searchexpr].field[aModBonus].value
      elseif (islinkage[psiattr] <> 0) then
debug "We have the linkage"
        attrbonus = linkage[psiattr].field[aModBonus].value
        endif

      ~ Our bonus PP = (attribute bonus * level) / 2, rounded down
      if (attrbonus > 0) then
debug "attrbonus is " & attrbonus
        bonus = (attrbonus * level) / 2
        bonus = round(bonus, 0, -1)
debug "bonus is " & bonus
        endif

      ~ Add our bonus power points to the maximum we have at this level
debug "bonus is " & bonus
debug "before add bonus, cPsiPPMax is " & field[cPsiPPMax].value

      field[cPsiPPMax].value = field[cPsiPPMax].value + bonus

debug "after add bonus, cPsiPPMax is " & field[cPsiPPMax].value

So, to compensate for this error, you should make an eval script which foreaches through the psionic classes, checks their associated attribute bonus, if it is 0, then subtract that class' maximum psionic power level from the PP point total. Since d20 doesn't have mechanics, you'll have to put it on something else added to all heroes, like a condition (I believe there is a Hasted condition in the Community files which will serve).

Here's the script I used:

PostAttr 11000

    var attrbonus as number

    foreach pick in hero from BaseClHelp where "Helper.Manifester"
      attrbonus = eachpick.linkage[psiattr].field[aModBonus].value

      if (attrbonus = 0) then
        ~ This part undoes the error on the total power points.
        hero.child[Psionics].field[tPPTotal].value -= eachpick.field[cPsiLevMax].value

        ~ It's too late to stop the points from being forwarded from this class, but this part at least fixes the display on our class tab.
        eachpick.field[cPsiPPMax].value -= eachpick.field[cPsiLevMax].value
        endif
      nexteach

I tested it a little bit, but not extensively. Tell me if you need help refining it.

[Sendric]

Originally Posted by Aaron

Here's the script I used:

PostAttr 11000

    var attrbonus as number

    foreach pick in hero from BaseClHelp where "Helper.Manifester"
      attrbonus = eachpick.linkage[psiattr].field[aModBonus].value

      if (attrbonus = 0) then
        ~ This part undoes the error on the total power points.
        hero.child[Psionics].field[tPPTotal].value -= eachpick.field[cPsiLevMax].value

        ~ It's too late to stop the points from being forwarded from this class, but this part at least fixes the display on our class tab.
        eachpick.field[cPsiPPMax].value -= eachpick.field[cPsiLevMax].value
        endif
      nexteach

I tested it a little bit, but not extensively. Tell me if you need help refining it.

Awesome. Thanks so much, Aaron. This was driving me nuts! I'll add it to the next community release. The only tweak I will have to make is that it needs to be "attrbonus <= 0" since this issue occurs when the bonus is negative too (though I'd like to think most players wouldn't build their characters like that).