Lone Wolf Development Forums  

Go Back   Lone Wolf Development Forums > Hero Lab Forums > HL - Pathfinder Roleplaying Game

Notices

Reply
 
Thread Tools Display Modes
rgulizia
Junior Member
 
Join Date: Apr 2015
Posts: 17

Old November 2nd, 2018, 04:29 PM
I am working on trying to create the Shadow Monk hybrid class from the Pathfinder Community and I can't seem to figure out how to change the Monk Unarmed damage. I updated the written text, but not the actual damage done by the PC.

Any assistance would be much appreciated!
rgulizia is offline   #1 Reply With Quote
Aaron
Senior Member
 
Join Date: Oct 2011
Posts: 6,793

Old November 6th, 2018, 10:26 AM
How are you going about it? Is this an archetype or something else? Are you replacing the Unarmed Strike monk ability with a new version or trying to modify the existing one?
Aaron is offline   #2 Reply With Quote
rgulizia
Junior Member
 
Join Date: Apr 2015
Posts: 17

Old November 6th, 2018, 06:31 PM
I'm just trying to modify the existing one. Just need to change the damage to slightly lower numbers. I am more than willing to create a new one as well. Let's call it Shadow Monk Unarmed Strike.
rgulizia is offline   #3 Reply With Quote
Aaron
Senior Member
 
Join Date: Oct 2011
Posts: 6,793

Old November 7th, 2018, 07:12 PM
If you're trying to modify the existing one then there are a couple ways to go about it. You could add or subtract effective levels (by manipulating the xEffectLev field on the class special). If its not a level adjustment but some different rate of advancement then you could copy the base ability, modify its scripts and save a new version (then use Replaces Thing ID to replace the old with the new). Replace Thing ID does have the drawback of not getting any subsequent changes we make to the base version of the ability. A third way to handle it would be to do the copy and mod, but attach the new version to an archetype, if this is a mod of base monk. Keep in mind I have no clue what "the Shadow Monk hybrid class from the Pathfinder Community" means.

I think it would be helpful if you posted how your version's text goes, and how you need things to differ from what the normal unarmed strike does.
Aaron is offline   #4 Reply With Quote
ShadowChemosh
Senior Member
Volunteer Data File Contributor
 
Join Date: Jan 2010
Location: Chicago, IL (USA)
Posts: 10,729

Old November 7th, 2018, 07:31 PM
Quote:
Originally Posted by Aaron View Post
Keep in mind I have no clue what "the Shadow Monk hybrid class from the Pathfinder Community" means.
Don’t feel bad as I don’t know what this means either.

Hero Lab Resources:
Pathfinder - d20pfsrd and Pathfinder Pack Setup
3.5 D&D (d20) - Community Server Setup
5E D&D - Community Server Setup
Hero Lab Help - Hero Lab FAQ, Editor Tutorials and Videos, Editor & Scripting Resources.
Created by the community for the community
- Realm Works kickstarter backer (Alpha Wolf) and Beta tester.
- d20 HL package volunteer editor.
ShadowChemosh is offline   #5 Reply With Quote
charlieluce
Senior Member
 
Join Date: Jul 2008
Posts: 1,321

Old November 7th, 2018, 08:43 PM
I'm pretty sure that it's this Shadow Monk.

Currently Running: Pathfinder Second Edition
Currently Playing:
Pathfinder First Edition, Star Trek Adventures
Former HL Games: D&D 4e & 5e, Mutants & Masterminds 2E & 3E, Savage Worlds
charlieluce is offline   #6 Reply With Quote
rgulizia
Junior Member
 
Join Date: Apr 2015
Posts: 17

Old November 13th, 2018, 05:47 PM
charlieluce, you got it! Thanks. I should have posted the link first....
rgulizia is offline   #7 Reply With Quote
Aaron
Senior Member
 
Join Date: Oct 2011
Posts: 6,793

Old November 15th, 2018, 11:15 AM
So, how's it going? Did you try one or more of the suggestions above? Did they work, or do you need more help?
Aaron is offline   #8 Reply With Quote
rgulizia
Junior Member
 
Join Date: Apr 2015
Posts: 17

Old November 16th, 2018, 04:23 PM
I'm going to need more help. I don't know what you mean by "modify the scripts" Where is the list of damage progression by level? If I can find that, then I can probably update the ability. I found the text, but not where it actually does the damage in class abilities.
rgulizia is offline   #9 Reply With Quote
Aaron
Senior Member
 
Join Date: Oct 2011
Posts: 6,793

Old November 19th, 2018, 05:47 PM
So if you make a copy of the Unarmed Strike Class special, you'll see that it bootstraps an ability called xMnkUnarm, which it then adds to the value of in this script:

PostLevel 4000
Code:
      ~ only perform the rest on the first copy
      doneif (tagis[Helper.FirstCopy] = 0)

      ~ If we're not shown, just get out now
      doneif (tagis[Helper.ShowSpec] = 0)

      ~ If we're disabled, do nothing
      doneif (tagis[Helper.SpcDisable] <> 0)

      ~Add our levels to the unarmed attack damage helper
      #value[xMnkUnarm] += field[xAllLev].value

      if (field[xAllLev].value < 4) then
        field[abText].text = "1d6"
      elseif (field[xAllLev].value < 8) then
        field[abText].text = "1d8"
      elseif (field[xAllLev].value < 12) then
        field[abText].text = "1d10"
      elseif (field[xAllLev].value < 16) then
        field[abText].text = "2d6"
      elseif (field[xAllLev].value < 20) then
        field[abText].text = "2d8"
      else
        field[abText].text = "2d10"
        endif
If you copy xMnkUnarm you'll see that it has only one script, which takes the value field and changes it into a damage tag (this is the procedure MnkWepBase), which it then applied to the unarmed weapon.

PostLevel 5000
Code:
      ~If our effective monk level is 0 or less, we don't change the damage at all
      doneif (field[abValue].value <= 0)

      ~ If we're disabled, do nothing
      doneif (tagis[Helper.SpcDisable] <> 0)

      perform assign[Helper.ShowSpec]

      ~ Get our unarmed strike pick, delete the damage tag from it, and assign
      ~ a new damage tag.

      ~ this has been modified to use the MnkWepBase routine
      ~ since that procedure puts the wMain tag on us, we will need to
      ~ push it to wUnarmed when we are done

      var level as number
      level = field[abValue].value

      call MnkWepBase

      ~ clear our wUmarmed and give it our wMain tag
      perform hero.child[wUnarmed].delete[wMain.?]
      perform hero.child[wUnarmed].pushtags[wMain.?]

      ~ set our dice damage in abText

      var dicetext as string

      call wMainText
      field[abText].text = dicetext
And here is what happens in that "MnkWepBase" procedure call

Code:
    ~ this is for setting the base damage tag for the
    ~ monk's unarmed strike ability and abilities that
    ~ gain benefits like that (for example the brawler)

    ~ INPUT
    ~ level is our level

    ~ we assuming that the wielder is medium, because
    ~ that is what wMain tags assume. Damage dice are then adjusted up or down
    ~ appropriately based on size.

    var level as number

    if (level >= 20) then
      ~ Medium folks get 2d10 at this level.
      perform assign[wMain.2d10]
    elseif (level >= 16) then
      ~ Medium folks get 2d8 at this level.
      perform assign[wMain.2d8]
    elseif (level >= 12) then
      ~ Medium folks get 2d6 at this level.
      perform assign[wMain.2d6]
    elseif (level >= 8) then
      ~ Medium folks get 1d10 at this level.
      perform assign[wMain.1d10]
    elseif (level >= 4) then
      ~ Medium folks get 1d8 at this level.
      perform assign[wMain.1d8]
    else
      ~ Medium folks get 1d6 at this level.
      perform assign[wMain.1d6]
      endif
So if you want your unarmed damage advancement for the Shadow Monk to stack level for level with other Unarmed Strikes from, for example, normal monks or brawlers, then just bootstrap cMnkUnarm to your new class.

If you want it to stack with other unarmed strikes but at some other rate (for example, 2 levels of shadow monk count as 1 level of monk for unarmed strike), then create a new class ability (for example cShMUnarm), have that bootstrap xMnkUnarm, but add a different value in the bolded section of the first script.

If it does not stack with other unarmed strikes, or if the advancement is radically different from the one followed by monks, then you should probably create a new class ability but NOT bootstrap the helper ability. Instead, copy the script from the MnkWepBase procedure into your new ability, and tweak those if/then branches to your new rate of advancement. Then do the tag replacement on wUnarmed as shown in Code section 2 above.

Hope that helps!
Aaron is offline   #10 Reply With Quote
Reply

Thread Tools
Display Modes

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump


All times are GMT -8. The time now is 07:08 AM.


Powered by vBulletin® - Copyright ©2000 - 2024, vBulletin Solutions, Inc.
wolflair.com copyright ©1998-2016 Lone Wolf Development, Inc. View our Privacy Policy here.