Community Effort: Feats

[daplunk]

Hi Everyone,

This is a listing of the scripts required to add the missing 5e feats into Hero Labs 5e SRD. This does not list the feat descriptions. You will need to copy those in from your PHB.

GREEN = Functional
ORANGE = Partially Functional
RED = Yet to be automated.

To complete this WE NEED YOUR HELP.

Please take the time to look over the scripts provided. If you have the required knowledge to resolve some of the Orange and Red entries please post them in the comments below so that the master list can be updated.

See below (post 3) for a tutorial on how to add these in using the Hero Labs. Adding these in requires only your time and no programming knowledge.

CURRENT STATUS
COMPLETE: 87%
PARTIALLY COMPLETE: 4%
PENDING COMPLETION: 0%

OUTSTANDING
Spell Sniper - Currently does not restrict spell choice to only those with attack roles. To be implemented after next official patch.

COMMUNITY FILES
These feats are all currently being added to a Community Pack that will be made available in the near future. We have replaced all known missing functionality from the PHB and are preparing the files for release. Watch the forum boards for an announcement.

[daplunk]

FEAT LIST

PLAYER HAND BOOK

Actor
ADD Eval Scripts: hero.child[aCHA].field[aStartMod].value += 1

Alert
ADD Eval Scripts: #skillbonus[Initiative] = #skillbonus[Initiative] + 5

Athlete
ADD Array-Based Menu?
Row 0: Strength
Row 1: Dexterity

ADD Eval Scripts
if (field.value = 0) then
hero.child[aSTR].field[aStartMod].value += 1
elseif (field.value = 1) then
hero.child[aDEX].field[aStartMod].value += 1
endif


[U]Charger
TICK: Show in Activated Abilities List?
Activation Name: Activate Charge (+5 bonus attack / ignore if pushing)
Eval Script:
doneif (field[abilActive].value = 0)
foreach pick in hero from BaseWep where "(wCategory.Melee)"
eachpick.field[atmBonus].value += 5
nexteach

[U]Crossbow Expert
Just Text

Defensive Duelist
Add Expr-reqs:
Message: Dexterity 13 required.
Pre-requisite Expression: #attrvalue[aDEX] >= 13
Tick: is Error? and Highlight Panel?

Add Eval Scripts
Phase: Post-attributes
Script: doneif (tagis[Helper.ShowSpec] = 0)

doneif (tagis[Helper.Disable] <> 0)

doneif (field[abilActive].value = 0)

hero.childfound[ArmorClass].field[Bonus].value += hero.child[ProfBonus].field[tProfBonus].value

Duel Wielder
ADD Eval-Script:
Phase: Post-Attributes
Script:
doneif (tagis[Helper.ShowSpec] = 0)

doneif (tagis[Helper.Disable] <> 0)

field[abValue].value = 0

foreach pick in hero from BaseWep where "(Hero.OffHand & !wProperty.TwoHanded)"
perform eachpick.assign[wProperty.Light]
field[abValue].value = 1
nexteach

hero.childfound[ArmorClass].field[Bonus].value += field[abValue].value

Dungeon Delver
Just Text

Durable
Add Eval Scripts: hero.child[aCON].field[aStartMod].value += 1

Elemental Adept
Coming in the community pack. Has dependencies on multiple files / things.

Great Weapon Master
TICK: Show in Activated Abilities List?
ADD Activation Name: Activate Great Weapon Master (-5 to hit, +10 dmg)
ADD Eval Script:
doneif (field[abilActive].value = 0)
foreach pick in hero from BaseWep where "(wProperty.Heavy)"
eachpick.field[atmBonus].value -= 5
eachpick.field[dmmBonus].value += 10
nexteach

Healer
Just Text

Heavily Armored
Add Eval Scripts:
hero.child[aSTR].field[Bonus].value += 1
perform hero.assign[ArmProfGrp.ArmorHeavy]

Add Expre-reqs
Message: Proficiency with medium armor required.
Is Error: Ticked
Highlight Panel: Ticket
Pre-requisite Expression: tagis[ArmProfGrp.ArmorMed] <> 0

Heavy Armor Master
ADD Eval Scripts: #skillbonus[aSTR] = #skillbonus[aSTR] + 1
ADD Expr-reqs: Message: Proficiency with heavy armor required.
Is Error: Ticked
Highlight Panel: Ticket
Pre-requisite Expression: tagis[ArmProfGrp.ArmorHeavy] <> 0

Inspiring Leader
Add Expr-reqs:
Message: Charisma 13 required.
Pre-requisite Expression: #attrvalue[aCHA] >= 13
Tick: is Error? and Highlight Panel?

Keen Mind
Add Eval Scripts: #skillbonus[aINT] = #skillbonus[aINT] + 1

Lightly Armored
ADD Array-Based Menu?
Row 0: Strength
Row 1: Dexterity

ADD Eval Scripts
if (field.value = 0) then
hero.child[aSTR].field[aStartMod].value += 1
elseif (field.value = 1) then
hero.child[aDEX].field[aStartMod].value += 1
endif

perform hero.assign[ArmProfGrp.ArmorLight]


[U]Linguist
Add Eval Scripts: #skillbonus[aINT] = #skillbonus[aINT] + 1
hero.child[resLangBck].field[resMax].value += 3

[U]Lucky
Charge Information:
TICK: Show in Tracked Resources List?
Base Charges: 3
Usage period: /long rest

Mage Slayer
Text Only

Magic Initiate
Complete: Coming in the Community pack

Martial Adept
Implemented as part of the community pack.

Medium Armor Master
ADD Eval-Script:
Phase: Final
Priority: 1000
Script:
field[abValue].value = 0
foreach pick in hero from BaseArmor where "ArmorClass.Medium & Helper.CurrArmor"
field[abValue].value = 1
perform eachpick.delete[Helper.StealthDis]
nexteach
hero.childfound[ArmorClass].field[tACDexMod].value = minimum(hero.childfound[ArmorClass].field[tACDexMod].value + field[abValue].value, hero.childfound[aDEX].field[aModBonus].value)

ADD Expr-reqs
Message: Proficiency with medium armor required.
Is Error: Ticked
Highlight Panel: Ticked
Pre-requisite Expression:
tagis[Hero.ProfMedium] <> 0

Mobile
Add Eval Scripts: hero.child[Speed].field[tSpeed].value += 10

Moderately Armored
ADD Array-Based Menu?
Row 0: Strength
Row 1: Dexterity

ADD Eval Scripts
if (field.value = 0) then
hero.child[aSTR].field[aStartMod].value += 1
elseif (field.value = 1) then
hero.child[aDEX].field[aStartMod].value += 1
endif

perform hero.assign[ArmProfGrp.ArmorMed]
perform hero.assign[ArmProfGrp.Shields]


ADD Expr-reqs: Message: Proficiency with heavy armor required.
Is Error: Ticked
Highlight Panel: Ticket
Pre-requisite Expression: tagis[ArmProfGrp.ArmorLight] <> 0
TO DO: Add Proficiency with Shields

[U]Mounted Combatant
Text Only

[U]Observant
ADD Array-Based Menu?
Row 0: Intelligence
Row 1: Wisdom

ADD Eval Scripts
if (field.value = 0) then
hero.child[aINT].field[aStartMod].value += 1
elseif (field.value = 1) then
hero.child[aWIS].field[aStartMod].value += 1
endif



ADD Eval Script #2
Phase: Post-attributes, Priority: 1000
Note: This makes it so you can hover over the skill and see the passive skill.

var sPPercept as string
var sPInvest as string
var iPPercept as number
var iPInvest as number

iPPercept = hero.child[skPercep].field[skAttrBon].value+10+5
iPInvest = hero.child[skInvestig].field[skAttrBon].value+10+5
sPPercept = "passive Perception (" & iPPercept & ") [+5 bonus to your passive Wisdom (Perception)]"
sPInvest = "passive Investigation ("& iPInvest &") [+5 bonus to your passive Intelligence (Investigation)]"

#situational[hero.child[skPercep], sPPercept,field[thingname].text]
#situational[hero.child[skInvestig], sPInvest,field[thingname].text]

~#situational[hero.child[skPercep], "+5 bonus to your passive Wisdom (Perception)",field[thingname].text]
~#situational[hero.child[skInvestig], "+5 bonus to your passive Intelligence (Investigate)",field[thingname].text]

[U]Polearm Master
Text only

[U]Resilient
ADD Array Based Menu
Row 0: Strength
Row 1: Dexterity
Row 2: Constitution
Row 3: Intelligence
Row 4: Wisdom
Row 5: Charisma

ADD Eval Script
if (field.value = 0) then
hero.child[aSTR].field[aStartMod].value += 1
perform hero.assign[ProfSave.svSTR]

elseif (field.value = 1) then
hero.child[aDEX].field[aStartMod].value += 1
perform hero.assign[ProfSave.svDEX]

elseif (field[usrIndex].value = 2) then
hero.child[aCON].field[aStartMod].value += 1
perform hero.assign[ProfSave.svCON]

elseif (field[usrIndex].value = 3) then
hero.child[aINT].field[aStartMod].value += 1
perform hero.assign[ProfSave.svINT]

elseif (field[usrIndex].value = 4) then
hero.child[aWIS].field[aStartMod].value += 1
perform hero.assign[ProfSave.svWIS]

elseif (field[usrIndex].value = 5) then
hero.child[aCHA].field[aStartMod].value += 1
perform hero.assign[ProfSave.svCHA]

endif

[U]Ritual Caster
We have added the ability to select the 2 ritual spells.

To Do: Once initial spells are selected unlock ability to add higher level spells.

[U]Savage Attacker
Text only

Sentinel
Text only

Sharpshooter
TICK Show in Activated Abilities List?
Activation Name: Activate Sharpshooter (-5 to hit, +10 dmg)
ADD Eval Script:
doneif (field[abilActive].value = 0)
foreach pick in hero from BaseWep where "(wCategory.RangeProj | wCategory.RangeThrow | wCategory.Firearm)"
eachpick.field[atrBonus].value -= 5
eachpick.field[dmrBonus].value += 10
nexteach


Shield Master
Text only

Skilled
Implemented, coming as part of the community pack.

Skulker
Add Expr-reqs:
Message: Dexterity 13 required.
Pre-requisite Expression: #attrvalue[aDEX] >= 13
Tick: is Error? and Highlight Panel?

Spell Sniper
This is now complete and will be included in the community pack. Has a number of dependencies thus not copied here.
Currently does not restrict spell choice to only those with attack roles. To be implemented after next official patch.

Tavern Brawler
This is now complete and will be included in the community pack. Has a number of dependencies thus not copied here.

Tough
ADD Eval Script #1:
Phase: Post-Levels
Priority: 5000
Script:
field[abValue].value += maximum(herofield[tHitDice].value, 1)*2

ADD Eval Script #2:
Phase: Post-Levels
Priority: 15000
Script:
~if we've been disabled, get out now
doneif (tagis[Helper.Disable] <> 0)

herofield[tBonusHP].value += field[abValue].value


War Caster

ADD Pre-reqs
Message: You must be able to cast at least one spell.
Is Error: Ticked
Highlight Panel: Ticked
Pre-requisite Script:

var iTotal as number

iTotal = iTotal + #levelcount[Bard]
iTotal = iTotal + #levelcount[Cleric]
iTotal = iTotal + #levelcount[Druid]
iTotal = iTotal + #levelcount[Sorcerer]
iTotal = iTotal + #levelcount[Warlock]
iTotal = iTotal + #levelcount[Wizard]

if (#levelcount[Paladin] >1) then
iTotal = iTotal + #levelcount[Paladin]
endif
if (#levelcount[Ranger] >1) then
iTotal = iTotal + #levelcount[Ranger]
endif
if (hero.child[RaceHelper].field[rSpAtk].value >0) then
iTotal = iTotal + 1
endif

@valid = 0
if (iTotal >0) then
@valid = 1
endif

Weapon Master
We have this functioning however it is quite involved. We will release this shortly as part of the community pack.

[daplunk]

HOW TO ADD A CUSTOM FEAT

1. Open Hero Labs
2. Click Tools > Show Editor
3. Click File > New Data File
4. Select Feat tab.
5. Click New(Blank)
6. Enter Name
7. Enter Unique ID
8. Enter Summary Text
9. Enter Description Text
10. See post above for unique changes that need to be made.
11. Some of the common sections that require changes per above have been highlighted in pink.
https://scontent.fmel1-1.fna.fbcdn.net/hphotos-xpl1/t31.0-8/12628611_10208335783372772_237814410390912005_o.jp g

12. This is what the Eval Scripts screen looks like.
https://scontent.fmel1-1.fna.fbcdn.net/hphotos-xft1/v/t1.0-9/12646994_10208335793973037_123820705435420487_n.jp g?oh=14c4d2c9d7101c42870827e0a85fd29d&oe=5743E6D7

13. This is what the Expr-reqs screen looks like.
https://scontent.fmel1-1.fna.fbcdn.net/hphotos-xfp1/v/t1.0-9/481157_10208335797853134_3052729844839748573_n.jpg ?oh=afce9a3729a1a743ce88f9e5baf9dc10&oe=572B082D

[MNBlockHead]

Thanks for posting this. Very helpful!

[Elindor]

Tough - cribbed from Hill Dwarf's Toughness

2 evaluation scripts, both Post-levels phase.
Priority 5000
field[abValue].value += maximum(herofield[tHitDice].value, 1)*2

Priority 15000
~if we've been disabled, get out now
doneif (tagis[Helper.Disable] <> 0)

herofield[tBonusHP].value += field[abValue].value

[Elindor]

I've almost got Sharpshooter (and, by extension, Great Weapon Master) nailed for scripting the mechanics. You will need to check "Show in Activated Ability List" and set an Activation Name.

doneif (field[abilActive].value = 0)
foreach pick in hero from BaseWep where "(wCategory.RangeProj | wCategory.RangeThrow | wCategory.Firearm)"
eachpick.field[atrBonus].value -= 5
eachpick.field[dmrBonus].value += 10
nexteach

Now, when you have Sharpshooter selected, a check box will appear on the in play tab. Checking the box will change the attack/damage values automatically. It does not, however, test for proficiency - not sure how to do that yet.

For Great Weapon Master, replace (wCategory.RangeProj etc) with wProperty.Heavy, and use atmBonus and dmmBonus.

Once the Weapon Proficiency test is sorted, it should hopefully slot into the where expression - but for now, it'll do - just hold the honour system there.

[daplunk]

Thanks Elindor!

They both work wonderfully :D

If anyone has knowledge they can share please don't be shy!

[daplunk]

For Great Weapon Master, replace (wCategory.RangeProj etc) with wProperty.Heavy, and use atmBonus and dmmBonus.

Have you got this working? My attempts are failing :( No changes are being made to anything visible on the In-Play tab.

doneif (field[abilActive].value = 0)
foreach pick in hero from BaseWep where "(wCategory.Heavy)"
eachpick.field[atmBonus].value -= 5
eachpick.field[dmmBonus].value += 10
nexteach

[Elindor]

Here's the codeblock

doneif (field[abilActive].value = 0)

foreach pick in hero from BaseWep where "wProperty.Heavy"
eachpick.field[atmBonus].value -= 5
eachpick.field[dmmBonus].value += 10
nexteach

[daplunk]

Got it. Change wCategory.Heavy to wProperty.Heavy

doneif (field[abilActive].value = 0)
foreach pick in hero from BaseWep where "(wProperty.Heavy)"
eachpick.field[atmBonus].value -= 5
eachpick.field[dmmBonus].value += 10
nexteach

[MagicSN]

Hmmm, seems to be easier than I thought with the editor after all...

Still would prefer a .dat files release so one can get the complete overview of things in the implementation.

[Elindor]

I'm probably not going to be contributing to feats too much for the rest of the week - my priority is (hopefully understandably) covering the non-SRD material being used in the D&D game I'm running. I think I'm doing quite well - in addition to all of the feats, I've got one subrace and three sub classes (with all features) in a usable state (not as polished as I'd like, but I take what I can get), and a fallback strategy for Variant Human if I can't work out how to add a feat that the user can choose. So my immediate plan will be to deal with the two remaining subclasses and add in the spells I need (even if they're just placeholders at this time).

There is, however, some interesting design space in the feats, so I'll probably swing back into it in short order. But for now, sleep beckons - I've got work in the morning *yawn*

[Tesh]

Not sure if this is correct thread to ask this question, but if you are not a programmer or the knowledge do all the editing that you guys are doing, is there is there away to add them or just need to wait for updates?

[daplunk]

This information is enough for a non programmer to add this information in. You are just copying the steps and code provided into the matching fields in the editor.

The green ones are complete and functional. Orange is partially complete. Red is still work in progress.

I will post a tutorial with images in a bit as an example.

[ShadowChemosh]

This information is enough for a non programmer to add this information in. You are just copying the steps and code provided into the matching fields in the editor.

The green ones are complete and functional. Orange is partially complete. Red is still work in progress.

I will post a tutorial with images in a bit as an example.
Why go through all that instead of just making actual .user files that can be shared? As has been mentioned the community can add the missing pieces of the SRD.

If all the separate people adding stuff started to work together it would go so much faster. Right now its like 20 people each doing there own thing. :p

[daplunk]

Its probably the way to go. I'm assuming however changes will need to be made.

Feat Names changed
Feat Descriptions removed

I'm assuming community files can only contain the mechanism.

Can anyone confirm?

[ShadowChemosh]

I'm assuming community files can only contain the mechanism.

Can anyone confirm?
Yep it has been CONFIRMED (http://forums.wolflair.com/member.php?u=25).

Basically you can most likely get away with the same "Name" of a Thing but you only want to list the Mechanics of the ability. So lets say "Dodge" feat (Sorry I don't know 5e) from 3.5. Call it "Dodge" but list a very simple text of +1 AC bonus.

Then take a look at my NOTE (http://forums.wolflair.com/showpost.php?p=223009&postcount=23) here about consistent file names and pick a two digit unique ID and how to set that.

Next stage of this is to compile the .user files into working version called Package or .hl file. This can be setup on the community servers with a working Update URL. Meaning that people will be able to download and install this community Pack really easily. In addition HL will tell gamers when a new version is out and will even prompt gamers to download and install.

This means you reach a MUCH larger audience. :)

[daplunk]

Thanks Shadow.

Not sure I'm the right person to be taking the lead on this. The only reason i have availability is because i'm home with a 2 week old /zzzzzzz

[daplunk]

NOTES - Pathfinder Scripting:

Two Weapon Defense

~ If we're disabled, do nothing
doneif (tagis[Helper.FtDisable] <> 0)

~ Check to see if we have something equipped in each hand
doneif (hero.tagis[Hero.EquipMain] + hero.tagis[Hero.EquipOff] < 2)

~ Check to see that we have at least two weapons equipped, or a double
~ weapon
if (hero.tagcount[Hero.EquipWep] < 2) then
doneif (hero.tagcount[Hero.EquipDbl] = 0)
endif

~ Check to see if our Unarmed Strike is selected in either main or off
~ hands
doneif (hero.child[wUnarmed].tagis[Hero.MainHand] + hero.child[wUnarmed].tagis[Hero.OffHand] > 0)

~ Otherwise, add a +1 Shield bonus to our AC
#applybonus[tACShield, hero.child[ArmorClass], field[abValue].value]

~ If we're in output mode, don't do anything
doneif (state.isoutput <> 0)

#appenddesc[pstTotDef,"{b}Addition from Two-weapon Defense{/b}: When wielding a double weapon or two weapons (not including natural weapons or unarmed strikes), you gain a " & signed(field[abValue].value) & " shield bonus to your AC.{br}{br}When you are fighting defensively or using the total defense action, this shield bonus increases to " & signed(field[abValue2].value) & "."]
#appenddesc[pstFtDefen,"{b}Addition from Two-weapon Defense{/b}: When wielding a double weapon or two weapons (not including natural weapons or unarmed strikes), you gain a " & signed(field[abValue].value) & " shield bonus to your AC.{br}{br}When you are fighting defensively or using the total defense action, this shield bonus increases to " & signed(field[abValue2].value) & "."]

~ if we're fighting defensively or total defense, the shield bonus increases to +2
if (#hascondition[pstFtDefen] + #hascondition[pstTotDef] <> 0) then
#applybonus[tACShield, hero.child[ArmorClass], field[abValue2].value]
endif

Aldori Dueling Mastery


~ If we're disabled, do nothing
doneif (tagis[Helper.FtDisable] <> 0)

~ If we have a shield, do nothing, we are done.
doneif (hero.tagis[Hero.EquipShld] <> 0)

~ If we have something in our off hand, is it an Aldori Dueling sword wielded 2 handed? If so set our bonus to 1, if not, done.
var shield as number
if (hero.tagis[Hero.EquipOff] <> 0) then
foreach pick in hero from BaseWep where "IsWeapon.wDuelSwo"
if (eachpick.field[gIsEquip].value + eachpick.field[wIs2nd].value = 2) then
shield = 1
endif
nexteach

doneif (shield = 0)

~ If we don't have something in our off hand, is an Aldori Dueling sword equipped in 1 hand? If so set our bonus to 2, if not, done.
elseif (hero.tagis[Hero.EquipOff] = 0) then
foreach pick in hero from BaseWep where "IsWeapon.wDuelSwo"
if (eachpick.field[gIsEquip].value = 1) then
shield = 2
endif
nexteach
doneif (shield = 0)
endif

~ Add the shield bonus to our Value field, and then add that as a shield bonus to AC. Doesn't stack with other shield bonuses (like the spell)
field[abValue].value += shield
#applybonus[tACShield, hero.child[ArmorClass], field[abValue].value]


~ If we're disabled, do nothing
doneif (tagis[Helper.FtDisable] <> 0)

~ Assign the piercing weapon tag so dueling swords work with Duelist abilities.
foreach pick in hero from BaseWep where "IsWeapon.wDuelSwo"
perform eachpick.assign[wType.P]
nexteach

~ Do we have a dueling sword equipped in either hand? If so +2 Init.
foreach pick in hero from BaseWep where "IsWeapon.wDuelSwo"
if (eachpick.field[gIsEquip].value + eachpick.field[wIs2nd].value <> 0) then
hero.child[Initiative].field[Bonus].value += 2
endif
nexteach

Armor Proficiency (Heavy)

Type: Expr-reqs
Message: Armor Proficiency (Light) required.
tagis[Hero.ProfLight] <> 0
tagis[Hero.ProfMedium] <> 0

[Starchildren3317]

NOTES - Pathfinder Scripting:



So, you're the man, just saying.

[daplunk]

I'm really flying blind.

It's just a matter of trying to find places where similar code has already been provided and messing with it until it works. Really starting to hit some brick walls now though.

Would love a list of all the variables and classes available as half the challenge is figuring out the name of things. The documentation is ok but I suspect a lot may be missing.

Or it could be I'm just so tired that I dont see the answer even though it's right in front of me. #newbornlife

[Aaron]

"Develop -> Enable Data File Debugging" then you can "Develop -> Floating Info Windows -> Show Selection Tags/Fields" to see what unique IDs of existing Picks on the hero is, as well as what field values and tags are present.

[daplunk]

Oh snap /hugs

[Aaron]

You might also benefit from checking out my "intro to creating your own content" seminar from last gencon. It's on our youtube page, and I mention this tip there (among others). It is focused on pathfinder, but many of the concepts are shared.

[Enforcer84]

Thank you for your excellent work everyone!

[daplunk]

Team,

We are looking for a volunteer or two to go through the feat text and re-write the names and descriptions in a way that we can use them without breaching any rules.

There are a number of us now working in the background making some significant progress on the missing content.

Please send me a message if you are keen on helping out.

Note: No programming skills required. Just good English :)

[Entola]

I am still learning how to use the editor and would like to help out but I am clearly missing something basic. I have added the feat Alert in the Hero Lab Editor. I saved it but when I click "Test Now" nothing happens. It says, You may now use "Alert" within Hero Lab" and I have added my source to the character, but I don't have a Feats Tab. What am I missing?

[Elindor]

Advance a class to level 4, and select the feat instead of an ability score increase.

[Elindor]

Defensive Duelist Eval Script
Tick "Show in Activated Abilities list"

Run Post-Attributes

doneif (tagis[Helper.ShowSpec] = 0)

doneif (tagis[Helper.Disable] <> 0)

doneif (field[abilActive].value = 0)

hero.childfound[ArmorClass].field[Bonus].value += hero.child[ProfBonus].field[tProfBonus].value

That last bit adds the current Proficiency bonus to AC for when it's active.

[Entola]

Advance a class to level 4, and select the feat instead of an ability score increase.

So you can't houserule a starting feat?

[Tamhansen]

I'm happy to help rewriting feats and feat texts for you. At least I'd feel like I'm helping, because the coding is way over my head in most places.

[Entola]

Advance a class to level 4, and select the feat instead of an ability score increase.

NM I figured it out.

[MardukBathory]

Grappler is missing from the list as functional, partially functional or to be automated.

I know somebody is probably on this but I thought I'd say this just in case.

[daplunk]

Grapppler was released with the SRD. It's already there.

[Mergon]

For those of you, like myself, who want to add a bonus feat, here is a work around. I could not find a way to add a generic bonus feat, but I did find a way to add a bonus class feat.

Go to the General > Adjustments tab.
Add a new Adjustment.
Set Minimum & Maximum adjustment to 1.
Set 'No Incrementer' & 'No Plus Sign'.
Click on Eval Scripts
Click to add another eval script.
Set Phase to First. (I used a Priority of 20000 but I am still new to scripting)
Copy/Paste the code below into the Script box.
Save & click Test Now.

You will now have a new Adjustment that allows to you pick a class you possess and grant it a bonus feat. A cludgy workaroudn I know, but it works for me.

~ Add 1 feat to your feat total.

~ If we're not enabled, get out now
doneif (field[pIsOn].value = 0)

~ If we have not chosen a class, get out now.
doneif (field[pChosen].ischosen = 0)

perform field[pChosen].chosen.pulltags[sClass.?]

~ hero.child[pChosen].field[cBonFtMax].value += 1
field[pChosen].chosen.field[cBonFtMax].value += 1

[Mergon]

For the Heavy Armored feat:

Virtually the same Expr-Reqs code from the Heavy Armor Master feat can be used:

Message: Proficiency with medium armor required.
Is Error: Ticked
Highlight Panel: Ticket
Pre-requisite Expression: tagis[ArmProfGrp.ArmorMed] <> 0

[daplunk]

You should send me your email Mergon.

[Mergon]

You should send me your email Mergon.

How do I send it to you and not everyone in the topic? :)

[daplunk]

Hover over my name, should be an option to message me privately.

[Mergon]

For the Mobile feat, your might want to make a slight change to the Eval script:

Instead of
hero.child[Speed].field[Bonus].value = hero.child[Speed].field[Bonus].value + 10

you make want to use:
hero.child[Speed].field[tSpeed].value = hero.child[Speed].field[tSpeed].value + 10

What this does is sets your base Speed to 40 instead of 30/40.

[Mathias]

Or how about

hero.child[Speed].field[tSpeed].value += 10

For less typing.

Here's the relevant article about math & text operations in Hero Lab: http://forums.wolflair.com/showthread.php?t=21668

[daplunk]

Thanks i forgot about that.

[Mergon]

So did I. :)

[Mergon]

Tavern Brawler feat

To grant Unarmed Strikes 1d4 damage:

Go to Bootstraps and add:
wUnarmed

On the new Bootstrap click on fields add add 2 fields;
Field 1: Field Id (wDieCount), Value: 1
Field 1: Field Id (wDieSize), Value: 4

As to the Improvised Weapon proficiency, I discovered that weapons have Improvised Ranged and Melee Weapon proficiencies listed under Proficiency Required. The tags for wProfReq are ImprovRng & ImprovMel.

I tried using:

perform hero.assign[WepProf.ImprovMel]
perform hero.assign[WepProf.ImprovRng]

to push these Profciencies on to the hero, but either I am doing somethign wrong, or there is an issue with these tags. I am not a good enough scripter to know which.

[Mergon]

Warcaster pre-requiste

Note: Due to the lack of caster archtypes for the fighter & rogue at this time, this Pre-reqs script does not check to see if they have spellcasting ability at this time.

This script goes in the Pre-reqs of the feat.

var iTotal as number

iTotal = iTotal + #levelcount[Bard]
iTotal = iTotal + #levelcount[Cleric]
iTotal = iTotal + #levelcount[Druid]
iTotal = iTotal + #levelcount[Sorcerer]
iTotal = iTotal + #levelcount[Warlock]
iTotal = iTotal + #levelcount[Wizard]

if (#levelcount[Paladin] >1) then
iTotal = iTotal + #levelcount[Paladin]
endif
if (#levelcount[Ranger] >1) then
iTotal = iTotal + #levelcount[Ranger]
endif

@valid = 0
if (iTotal >0) then
@valid = 1
endif


There is probably a shorter way to do this, but I haven't been able to get anythign else to work so far. :)

[daplunk]

Well done Mergon!

[daplunk]

Mergon - send me a PM and ill give you access to the WIP so you can contribute directly if you like. Just need your email.

[nichollsr]

Is there anywhere i can start to learn how to do the script ? Id love to help out on this but not sure how.

[daplunk]

From the editor use the help menu. it's what's available currently. Most of us are opening up existing items in the editor to find similar code and reworking it to meet our needs from what i can gather.

[nichollsr]

From the editor use the help menu. it's what's available currently. Most of us are opening up existing items in the editor to find similar code and reworking it to meet our needs from what i can gather.

Cool, thanks Daplunk. I will start playing around. Ive got a lot of stuff id like to see in there over and above the stuff in the rulebooks hence needing to learn !

[Mergon]

daplunk:

I thought I had sent you a pm with my email address. Let me try again.

[daplunk]

Front post updated with latest changes.

[MardukBathory]

So you can't houserule a starting feat?
Maybe if somebody figures out how to make the human variant you can just use that.

[MardukBathory]

Is this meant to be inside the same box? (See attachment, circled items)

[Mergon]

Maybe if somebody figures out how to make the human variant you can just use that.

For the moment, as a kludge, I've been using the feature to add bonus class feats to grant bonus feats. it works, but I'd rather add them where they rightfully belong. :)

[Mergon]

Is this meant to be inside the same box? (See attachment, circled items)

Hmm, I'm not seeing any attachments . . .

[MardukBathory]

*sigh* It's been one of those years....
Here it is.

[Mergon]

*sigh* It's been one of those years....
Here it is.

Yea, that is supposed to be in the same box. The first part of the script adds +1 to iTotal if any of those classes , which are all spellcasting classes at the levels tested for,.

The 2nd part, checks to see if iTotal is higher than 0, which means the character has at least 1 class with spellcasting ability.

Since this is a Pre-requisites test, we need to set @valid to 1 if the iTotal is greater than 0.

I hope I explained that clearly . . .

[ShadowChemosh]

Maybe if somebody figures out how to make the human variant you can just use that.
Maybe you guys are talking different things but I posted a solution HERE (http://forums.wolflair.com/showpost.php?p=223461&postcount=7) for getting a Bonus Feats tab to appear in 5e. Does that help with this issue?

[Mergon]

Maybe you guys are talking different things but I posted a solution HERE (http://forums.wolflair.com/showpost.php?p=223461&postcount=7) for getting a Bonus Feats tab to appear in 5e. Does that help with this issue?

Shadow:

I had missed that. I'll take a closer look at it now that I have download the .user file. Thanks.

[MardukBathory]

What about High elves, Dark Elves & Tieflings who aren't in these classes? It's unlikely they'll take this feat but they could.War Caster

ADD Pre-reqs
Message: You must be able to cast at least one spell.
Is Error: Ticked
Highlight Panel: Ticked
Pre-requisite Script:

var iTotal as number

iTotal = iTotal + #levelcount[Bard]
iTotal = iTotal + #levelcount[Cleric]
iTotal = iTotal + #levelcount[Druid]
iTotal = iTotal + #levelcount[Sorcerer]
iTotal = iTotal + #levelcount[Warlock]
iTotal = iTotal + #levelcount[Wizard]

if (#levelcount[Paladin] >1) then
iTotal = iTotal + #levelcount[Paladin]
endif
if (#levelcount[Ranger] >1) then
iTotal = iTotal + #levelcount[Ranger]
endif

@valid = 0
if (iTotal >0) then
@valid = 1
endif

[Aaron]

What about High elves, Dark Elves & Tieflings who aren't in these classes? It's unlikely they'll take this feat but they could.

Then you're probably better off looking for at least one spell pick on the hero, than counting Classes tags.

[Mergon]

What about High elves, Dark Elves & Tieflings who aren't in these classes? It's unlikely they'll take this feat but they could.

Here is updated code that checks to see if the race/subrace has a spell attack bonus. if so, then it passes the test.
What's nice about this code addon is that it will function for races not yet in Hero Lab.

var iTotal as number

iTotal = iTotal + #levelcount[Bard]
iTotal = iTotal + #levelcount[Cleric]
iTotal = iTotal + #levelcount[Druid]
iTotal = iTotal + #levelcount[Sorcerer]
iTotal = iTotal + #levelcount[Warlock]
iTotal = iTotal + #levelcount[Wizard]

if (#levelcount[Paladin] >1) then
iTotal = iTotal + #levelcount[Paladin]
endif
if (#levelcount[Ranger] >1) then
iTotal = iTotal + #levelcount[Ranger]
endif
if (hero.child[RaceHelper].field[rSpAtk].value >0) then
iTotal = iTotal + 1
endif

@valid = 0
if (iTotal >0) then
@valid = 1
endif

[MardukBathory]

Thanks, you're a legend!

[daplunk]

Very nice - that worked for all the elemental adept feats too!

[blackbloodtroll]

I would like to see if I can give a hand. I suck at using the editor, but I could maybe see what I can do. Can please someone send me, or somehow otherwise give me access to the .dat files?

[daplunk]

At this stage we are in need of people with scripting skills and knowledgeable in the use of the editor.

Unfortunately we cannot give people access at this stage who cannot contributing in this way due to the legal restrictions imposed on us.

[blackbloodtroll]

Well, that's too bad.

[Elindor]

Here is updated code that checks to see if the race/subrace has a spell attack bonus. if so, then it passes the test.
What's nice about this code addon is that it will function for races not yet in Hero Lab.

How about this? just check to see if there are any spells? That way, it will work for all classes and races, and will detect them when added by Feats

foreach pick in hero from BaseSpell where "!Helper.ItemSpell"
@valid = 1
done
nexteach


Correction, check for any spells which don't come from a magic item...

[daplunk]

Hi everyone,

We are very interested in talking to anyone has the following working:

Duel Wielder
Magic Initiate
Martial Adept
Medium Armor Master
Observant
Ritual Caster
Skilled
Spell Sniper
Tavern Brawler
Weapon Master

[Elindor]

Hi everyone,

We are very interested in talking to anyone has the following working:

Duel Wielder
Magic Initiate
Martial Adept
Medium Armor Master
Observant
Ritual Caster
Skilled
Spell Sniper
Tavern Brawler
Weapon Master

Dual Wielder - Post-Attributes, 100
doneif (tagis[Helper.ShowSpec] = 0)

doneif (tagis[Helper.Disable] <> 0)

field[abValue].value = 0

foreach pick in hero from BaseWep where "(Hero.OffHand & !wProperty.TwoHanded)"
perform eachpick.assign[wProperty.Light]
field[abValue].value = 1
nexteach

hero.childfound[ArmorClass].field[Bonus].value += field[abValue].value

and Medium Armor Master (Note - this doesn't change the Max Dexterity displayed on the armour itself, but it does modify the AC correctly and removes the Stealth Disadvantage note). Final Phase, priority 1000.

field[abValue].value = 0
foreach pick in hero from BaseArmor where "ArmorClass.Medium & Helper.CurrArmor"
field[abValue].value = 1
perform eachpick.delete[Helper.StealthDis]
nexteach
hero.childfound[ArmorClass].field[tACDexMod].value = minimum(hero.childfound[ArmorClass].field[tACDexMod].value + field[abValue].value, hero.childfound[aDEX].field[aModBonus].value)

[daplunk]

Thanks Elindor!

/updated

[Mergon]

daplunk:

This is the code I have been using for Observant:

if (field[usrIndex].value = 0) then
hero.child[aINT].field[aStartMod].value += 1
elseif (field[usrIndex].value = 1) then
hero.child[aWIS].field[aStartMod].value += 1
endif

#situational[hero.child[skPercep], "+5 bonus to your passive Wisdom (Perception)",field[thingname].text]
#situational[hero.child[skInvestig], "+5 bonus to your passive Intelligence (Investigate)",field[thingname].text]

It basically adds the bonus as situational text to the Perception & Investigation skills. So far, I have been unable to find any references to Passive skills in HL 5e SRD. This may be because SRD doesn't have Passives, but I don't know and am too lazy to look into SRD limitations. :)

[Mergon]

daplunk:

Disregard the above code. This new code places a passive Perception & passive Investigation value as a situational modifier on the skills themselves.

Eval Script #2
Phase: Post-attributes, Priority: 1000

var sPPercept as string
var sPInvest as string
var iPPercept as number
var iPInvest as number

iPPercept = hero.child[skPercep].field[skAttrBon].value+10+5
iPInvest = hero.child[skInvestig].field[skAttrBon].value+10+5
sPPercept = "passive Perception (" & iPPercept & ") [+5 bonus to your passive Wisdom (Perception)]"
sPInvest = "passive Investigation ("& iPInvest &") [+5 bonus to your passive Intelligence (Investigation)]"

#situational[hero.child[skPercep], sPPercept,field[thingname].text]
#situational[hero.child[skInvestig], sPInvest,field[thingname].text]

~#situational[hero.child[skPercep], "+5 bonus to your passive Wisdom (Perception)",field[thingname].text]
~#situational[hero.child[skInvestig], "+5 bonus to your passive Intelligence (Investigate)",field[thingname].text]

[daplunk]

You might find this website useful: http://www.5esrd.com/

Its a digital SRD and searchable.

You can see the listing for passive skills here: http://www.5esrd.com/using-ability-scores#TOC-Passive-Checks

LW have confirmed that passive skills are not currently tracked. I believe (hope) they are checking this out for a future release.

[Mergon]

daplunk:

I kind of figured that out after going through all the tags & fields on a character. That's why I set them up as #situationals for the time being. If you check your Perception & Investigation skills after taking Observant, you'll see passives at the top of each.

To the best of my knowledge, you ONLY get passive Investigate by taking the Observant feat. I'm goign to add an Adjustment for adding passive Perception until there is an official implementation of passives.

[daplunk]

From what I'm reading most skills would have a Passive score at all times its just that those would likely not come into play most of the time.

Technically a DM could ask for your passive Str for example. Obviously however most character sheets only list passive perception however the PHB refers to stealth and exploring using passive checks.

[TonganJedi]

Fantastic work on the script for Dual Wielder! One thing to note: it appears to adjust properly in the client, but doesn't appear properly on the character sheet.

For example, I selected the feet, equipped two rapiers, and the print preview shows both rapiers in the main hand and the bonus damage from the ability modifier is not removed from the off-hand weapon.

This could be an issue with the sheet generator, but I thought I'd point it out just in case. Thanks again!

[Elindor]

Fantastic work on the script for Dual Wielder! One thing to note: it appears to adjust properly in the client, but doesn't appear properly on the character sheet.

For example, I selected the feet, equipped two rapiers, and the print preview shows both rapiers in the main hand and the bonus damage from the ability modifier is not removed from the off-hand weapon.

This could be an issue with the sheet generator, but I thought I'd point it out just in case. Thanks again!

Dual Wielder doesn't affect damage - it's a hack to let non-light weapons be wielded without penalty in the off hand, by making the client see them as light, and only the weapon in the off-hand. Not perfect, but usable. If you put the rapier in the off-hand, it appears properly. I suppose removing the requirement for the weapon to be in the off hand would do the trick - just be sure to leave the exclusion for two handed weapons.

[daplunk]

Currently looking for any help on completing the following.

CURRENT STATUS
COMPLETE: 82%
PARTIALLY COMPLETE: 2%
PENDING COMPLETION: 7%

OUTSTANDING
The following are outstanding and delaying release of the Community Pack.
Ritual Caster - How to enable addition of new ritual spells once initial pick is complete.
Martial Adept - No progress
Skilled - No progress
Spell Sniper - No progress

[PinkRose]

Any thought to release a non-feat package?
Since they are optional for character creation, it seems a shame to hold back everything else.

[Colen]

For the mechanics of a feat like Ritual Caster that allowed the hero to pick spells, I would have the feat bootstrap a configurable ("Configure" tab in the editor) with the following settings in the Spells section:

Linked Attribute: Intelligence (StandardDC.aINT tag)
Caster Level: Class Level (Helper.ClsCastLev tag)
Spells Total: 2 (cfgMaxSp1 field)
Primary Spell Candidate: Helper.RitualSpel & sLevel.1 (cfgAllwSp1 field)

That would let you add 2 of any level 1 ritual to the hero on the "Ritual Caster" tab. You could use a menu selection to choose which class to restrict it to (and then modify the spell candidate tag expression appropriately), or just define separate "Ritual Caster (Wizard)", "Ritual Caster (Bard)" etc feats for each different class.

The other feats should be able to be implemented in the same with, with configurables - the exception is "Skilled", as I think you currently can't add skill or tool proficiencies via a configurable. We can fix that for next release - until then, you can simply tell the user add the proficiencies manually on the Skills tab.

Hope this helps!

[daplunk]

That's pretty much how it is working i believe. Tim made a configurable that we are referencing to. I'm currently working on modifying that same concept for Spell Sniper.

Ritual Caster has some more complexity in that we want to allow / guide the user to pick 2 1st level spells but once that is done they need to be able to add more Ritual spells depending on their level.

[daplunk]

At this stage the pack is much more than just single user files. It has been structured correctly in preparation for an official release file which means we have dependencies coming to and from multiple files.

I'm sure we could make a sub release with little effort but given we are only 3.5 Feats away from full functionality we are driving towards that goal.

Any thought to release a non-feat package?
Since they are optional for character creation, it seems a shame to hold back everything else.

[Colen]

That's pretty much how it is working i believe. Tim made a configurable that we are referencing to. I'm currently working on modifying that same concept for Spell Sniper.

Ritual Caster has some more complexity in that we want to allow / guide the user to pick 2 1st level spells but once that is done they need to be able to add more Ritual spells depending on their level.

Right now I think the total number of spells is fixed - we could add the ability to make that a minimum in the next release, but for now it's a fixed value.

Spell Sniper should be able to work the same way, except you're selecting cantrips instead of ritual spells.

[daplunk]

Yeah it wont take me long to work out Spell Sniper.

Which leave us with:
Martial Adept - No progress
Skilled - No progress but believe this is reliant on new functionality in next patch.

[daplunk]

@Colen,

For spell sniper, to restrict selection to only cantrips that have an attack roll, i assume i need to add a custom User Tag and then restrict the options to only spells containing that tag.

Sound about right?

~ Set the spell selection expression to only be the selected class
field[cfgAllwSp1].text &= " & (sLevel.0) & (" & tagids[sClass.?,"|"] & ")"

[Colen]

The problem is none of the SRD cantrips will have that tag. We can define a new tag for "spell with attack roll" in the next update, and you can use that in the tag expression and in your own spells once it's added.

For Martial Adept, that should be doable with a configurable as well - have it add custom abilities, and set the tag expression properly for battle master maneuvers (we used abCategory.FtrBMasMan in our examples).

[daplunk]

Thanks mate, that will make it alot easier. Ill have a crack at Martial Adept later tonight.

[azuravian]

I added Elemental Adept using the instructions on the front page and came across two issues. Firstly, it won't compile. Error message is:

'pre-requisite rule' script for Thing 'fElemAdept' calls a non-existent procedure for the active script context

I'm assuming this is due to the line
Call 5CHasSpell
but I'm not sure of how to fix it.

I searched around and found the other script for War Caster on page 7 and used it instead and was able to compile and the pre-requisite seems to work.

The second issue I found is that, although I can select the feat, I am unable to choose the damage type. I have added "Energy Type (Base 4)" to the "Select From..." under Item Selection. In the dropdown within the main app however, it just says "Nothing to Select".

[ShadowChemosh]

I added Elemental Adept using the instructions on the front page and came across two issues.
Elemental Adept currently only works if you have the 5e community pack loaded. This is because I created a "custom" validation procedure that will only work if you have the 5e Pack loaded. I did that as multiple feats needed to do the same logic test. You can tell because the procedure name starts with "5C" which stands for 5e Community.

In addition the custom expression uses Selection Helpers for "Energy Types" that I built for the 5e Pack. :)

Most likely best to just wait out the release of the Pack which should be soon...

[ShadowChemosh]

For example, I selected the feet, equipped two rapiers, and the print preview shows both rapiers in the main hand and the bonus damage from the ability modifier is not removed from the off-hand weapon.

This could be an issue with the sheet generator, but I thought I'd point it out just in case. Thanks again!
To get the sheet to display correctly you have do a "CTRL-K" and scroll to the bottom and turn on "Always Print 2-Weapon Attacks". Then the sheet will match the UI.

[CNYGamer]

The dual wielder feat as listed has a couple of problem:

(1).
If you equip a ranged weapon, such as hand crossbow, it will trigger the AC bonus.

(2).
If you equip a weapon in two hands, such as equipping a longsword in both the main and off hand, it will trigger the AC bonus.

I tinkered around with it, and this seems to get us a few steps closer toward something ideal:

~exit if disabled
doneif (tagis[Helper.Disable] <> 0)

~exit if fewer than two weapons are equipped
~keeps feat from triggering if a one-handed weapon
~is equipped in both hands
doneif (hero.tagcount[Hero.EquipWep] < 2)

~counter variable
field[abValue].value = 0

~add up total number of weapons in character's inventory
~that are equipped in the main hand and the off hand
foreach pick in hero from BaseWep where "(wCategory.Melee)"
if (eachpick.field[gIsEquip].value = 1) then
field[abValue].value += 1
endif
if (eachpick.field[wIs2nd].value = 1)then
field[abValue].value += 1
perform eachpick.assign[wProperty.Light]
endif
nexteach

~exit if there isn't a weapon in both the main hand
~and the off hand
doneif (field[abValue].value < 2)

~add 1 to armor class
hero.childfound[ArmorClass].field[Bonus].value += 1

It's quite inelegant, but there is still so much about the syntax of this scripting language that I don't know. And not having access to the scripts that make up the core 5e SRD rules for Hero Lab is also pretty crippling.

Jamie (CNYGamer)

[daplunk]

These have all been released in the 5e Community Pack (http://forums.wolflair.com/showthread.php?t=55090).

Please see the official thread for instructions on how to log issues and requests through to the main GitHub repository. This will ensure issues are properly tracked and maintained.